stats/commits-per-release.plot at master · curl/stats · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
# SVG output
load "stats/terminal.include"

# title
set title "Commits per release" font ",48"
# where's the legend
set key top center

# Identify the axes
#set xlabel "Time"
set ylabel "Number of commits"

set style line 1 \
    linecolor rgb '#c0c0ff' \
    linetype 1 linewidth 2

set style line 2 \
    linecolor rgb '#a0a000' \
    dt 1 linewidth 4

set style line 3 \
    linecolor rgb '#00c0ad' \
    dt 1 linewidth 4

set grid
unset border

# time formated using this format
set timefmt "%Y-%m-%d"
set xdata time
set xtics rotate time 1 years nomirror out
set ytics nomirror
unset mxtics

load "stats/logo.include"

# set the format of the dates on the x axis
set format x "%Y"
set datafile separator ";"
plot ARG1.'/commits-per-release.csv' using 1:3 with lines linestyle 1 title "Number of commits since previous release", \
 ARG1.'/commits-per-release.csv' using 1:4 with lines linestyle 3 title "All-time median", \
 ARG1.'/commits-per-release.csv' using 1:5 with lines linestyle 2 title "12 month average"